必要なパーツ

セロハンテープ、つまようじ、ティッシュペーパーは、サーボモータに持たせる白旗を作るためのものです。

• シャープ測距モジュール GP2Y0A21YK x1
• サーボモータ SG92R x1
• 電解コンデンサ 10μF x1
• Arduino UNO R3 x1
• ブレッドボード x1
• ジャンプワイヤ (適量)
• 短めのジャンプワイヤ (適量)
• セロハンテープ、つまようじ、ティッシュペーパー

回路図

GP2Y0A21YK は瞬間的に大きな電流が必要になることがあるため、電解コンデンサを付近に設置しています。出力電圧を A0 ピンで A/D 変換して読み取ります。Servo モーターはパルス幅によってその角度を指定します。Servo ライブラリを利用すれば Arduino の PWM ピンから簡単に制御できます。

http://schematics.com/project/white-flag-waver-48553/

制御プログラム

サーボモータの不要な振動を抑制するために、過去の距離センサの値を記憶して平均したり、一の位と十の位の値を切り捨てたりしています。servo.write() には 0-180 の値を入力できますが、距離センサが 3V 程度の電圧までしか出力しないため、実際に白旗が振り上がるのは 108 度程度までとなります。

#include <Servo.h>

#define SERVO_PWM_PIN 13
#define DISTANCE_INPUT_PIN 0

// サーボモータを制御するためのオブジェクトを生成
Servo servo;

// サーボモータをできるだけなめらかに制御するために、
// 過去の距離センサの値を記憶します。
const int BUF_SIZE = 64;
int buf[BUF_SIZE];
int k = 0;

void setup() {
  // サーボモータの初期化
  servo.attach(SERVO_PWM_PIN);

  // 距離センサの値で配列を初期化
  for(int i = 0; i < BUF_SIZE; ++i) {
    buf[i] = analogRead(DISTANCE_INPUT_PIN);
  }
}

void loop() {

  // 距離センサから値を読み取ります。
  buf[k] = analogRead(DISTANCE_INPUT_PIN);

  // 過去の距離センサの値を平均します。
  long avg = 0;
  for(int i = 0; i < BUF_SIZE; ++i) {
    avg += buf[i];
  }
  avg /= BUF_SIZE;

  // サーボモータの角度を計算して PWM 制御します。
  // 一の位と十の位を切り捨てることで、サーボモータの不要な振動を抑制します。
  int deg = map(avg/100, 0, 10, 0, 180); // 0-1023 を 0-180 に変換
  servo.write(deg);

  // 次のインデックスに進めます。
  k = (k + 1) % BUF_SIZE;
}